Media Informatics Msc

Dies ist Übersicht für den Studiengang Medieninformatik (Master of Science) an der Universität Regensburg.

ℹ️ Für direkte Informationen nutzen Sie die offizielle Homepage

Der Studiengang hat 16 Module mit 25 Kursen in einer Regelstudienzeit von 4 Semestern.

Der Übersicht von allen Mastermodulen ist unter dem Link verfügbar.

Studiengang

Links zu verschiedenen Visualisierungen

Beschreibung	Query-Ergebnis	SPARQL-Query
Wintersemester oder Sommersemster?	Link to the visualization	Link to the query
Empfohlenes Fachsemester	Link to the visualization	Link to the query
Bar Chart: Kurse pro Semester	Link to the visualization	Link to the query

Modulplan

Zeigt die Abhängigkeiten zwischen Modulen, sowie deren relevanten Modulpositionen Items used: M. Sc. Media Informatics (Q2886), Module (Q791), Mandatory (Q324)

Properties used: includes (P14), instance of (P3), depends on (P1), importance (P13)

#defaultView:Graph
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
PREFIX wd: <https://graphit.ur.de/entity/>
PREFIX p: <https://graphit.ur.de/prop/>
PREFIX ps: <https://graphit.ur.de/prop/statement/>
PREFIX pq: <https://graphit.ur.de/prop/qualifier/>
select distinct ?module ?moduleLabel ?rgb ?module2 ?module2Label
?position ?positionLabel 
# ?pCount
?course ?courseLabel
where {
  wd:Q2886 wdt:P14 ?module.
  ?module wdt:P3 wd:Q791.
  
  {
    
    # Only show a module position, if there are >1 included in a module.
    { SELECT ?module ?moduleLabel (COUNT(?position) as ?pCount) WHERE {
       ?module wdt:P14 ?position.
    } GROUP BY ?module ?moduleLabel
    }
    ?module wdt:P14 ?position.
    FILTER (?pCount > 1). 
  
  } UNION {
    
    # Select all other module normally
    { SELECT ?module ?moduleLabel ?module2 ?module2Label ?course ?courseLabel 
    WHERE {
      wd:Q2886 wdt:P14 ?module.
      ?module wdt:P3 wd:Q791.
      ?module wdt:P14 ?position.
      
      # Show the dependencies according to their importance (=qualifier), currently only "Mandatory" (Q324)
      OPTIONAL {
        ?module p:P1 ?statement.
        ?statement ps:P1 ?module2. 
        ?statement pq:P13 wd:Q324. # exclude this line to show dependencies of diff importance
      } 
      #OPTIONAL {?position wdt:P14 ?course}
    }
    }
    
  }
 
  BIND (IF(BOUND(?module2), "ffeec2","e3ffd9") as ?rgb)
  
  service wikibase:label { bd:serviceParam wikibase:language "de".}
} LIMIT 50

Try it!

Detailansicht

Zeigt die Module und Modulpositionen abhängig von Semester

Items used: M. Sc. Media Informatics (Q2886), Module (Q791), Module position (Q792), Semester number (Q3212)

Properties used: includes (P14), instance of (P3), in term (P34), depends on (P1)

#defaultView:Graph
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
PREFIX wd: <https://graphit.ur.de/entity/>
PREFIX p: <https://graphit.ur.de/prop/>
PREFIX ps: <https://graphit.ur.de/prop/statement/>
PREFIX pq: <https://graphit.ur.de/prop/qualifier/>

# Select all relevant variables for the graph visualization:
# - position & positionLabel: the module position (e.g. compulsory, elective)
# - module & moduleLabel: the module itself
# - rgb: color coding (yellow = has dependencies, green = no dependencies)
# - module2 & module2Label: a dependency of a module (if any)
# - term & termLabel: the recommended semester for the module
SELECT DISTINCT
  ?position ?positionLabel
  ?module ?moduleLabel ?rgb ?module2 ?module2Label
  ?term ?termLabel
WHERE {
  {
    { SELECT * WHERE {
        wd:Q2886 wdt:P14 ?module.
        ?module wdt:P3 wd:Q791.
        ?module wdt:P14 ?position.
        ?position wdt:P3 wd:Q792.
        OPTIONAL {
          ?position wdt:P34 ?term.
          ?term wdt:P3 wd:Q3212.
        }
        { SELECT ?module ?moduleLabel (COUNT(?position) AS ?pCount) WHERE {
            ?module wdt:P14 ?position.
          } GROUP BY ?module ?moduleLabel
        }
        ?module wdt:P14 ?position.
        FILTER (?pCount > 1).
      }
    }
  }
  UNION
  # Handles modules that have EXACTLY ONE position.
  {
    { SELECT ?module ?moduleLabel ?module2 ?module2Label ?term ?termLabel
      WHERE {
        wd:Q2886 wdt:P14 ?module.
        ?module wdt:P3 wd:Q791.
        ?module wdt:P14 ?position.
        ?position wdt:P3 wd:Q792.
        ?module wdt:P34 ?term.
        ?term wdt:P3 wd:Q3212.

        { SELECT ?module ?moduleLabel (COUNT(?position) AS ?pCount) WHERE {
            ?module wdt:P14 ?position.
          } GROUP BY ?module ?moduleLabel
        }
        ?module wdt:P14 ?position.
        FILTER (?pCount = 1).

        OPTIONAL {
          ?module p:P1 ?statement.
          ?statement ps:P1 ?module2.
        }
      }
    }
  }

  BIND(IF(BOUND(?module2), "ffeec2", "e3ffd9") AS ?rgb)

  # ─── LABELS ─────────────────────────────────────────────────────────────────
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
LIMIT 50

Try it!

Allgemeine Informationen

Studiengangsmetriken

Gibt zurück Anzahl der Module, Modulpositionen und Semester. Items used: M. Sc. Media Informatics (Q2886), Module (Q791), Module position (Q792), Semester number (Q3212) Properties used: includes (P14), instance of (P3), in term (P34) #defaultView:Table PREFIX wdt: <https://graphit.ur.de/prop/direct/> PREFIX wd: <https://graphit.ur.de/entity/> SELECT DISTINCT ?modules ?positions ?terms WHERE { { Select (COUNT (DISTINCT ?position) as ?positions) WHERE { wd:Q2886 wdt:P14 ?module. ?module wdt:P3 wd:Q791. ?module wdt:P14 ?position. ?position wdt:P3 wd:Q792 } } { Select (COUNT (DISTINCT ?module) as ?modules) WHERE { wd:Q2886 wdt:P14 ?module. ?module wdt:P3 wd:Q791. } } { Select (COUNT (DISTINCT ?term) as ?terms) WHERE { wd:Q2886 wdt:P14 ?module. ?module wdt:P3 wd:Q791. ?module wdt:P34 ?term. ?term wdt:P3 wd:Q3212. } } service wikibase:label { bd:serviceParam wikibase:language "de".} } Try it!