Dies ist Übersicht für den Studiengang Medieninformatik (Master of Science) an der Universität Regensburg.

ℹ️ Für direkte Informationen nutzen Sie die offizielle Homepage

{{#get_web_data:url=http://query.graphit.ur.de/proxy/wdqs/bigdata/namespace/wdq/sparql?query=%23defaultView%3ATable%0APREFIX%20wdt%3A%20%3Chttps%3A%2F%2Fgraphit.ur.de%2Fprop%2Fdirect%2F%3E%0APREFIX%20wd%3A%20%3Chttps%3A%2F%2Fgraphit.ur.de%2Fentity%2F%3E%0ASELECT%20%0ADISTINCT%20%3Fmodules%20%3Fpositions%20%3Fterms%20%0A%23%3Fposition%20%3FpositionLabel%20%0A%23%20(COUNT%20(DISTINCT%20%3Fposition)%20as%20%3Fpositions)%0AWHERE%20%7B%0A%20%20%7B%20Select%20(COUNT%20(DISTINCT%20%3Fposition)%20as%20%3Fpositions)%20WHERE%20%7B%0A%20%20wd%3AQ790%20wdt%3AP14%20%3Fmodule.%0A%20%20%3Fmodule%20wdt%3AP3%20wd%3AQ791.%0A%20%20%3Fmodule%20wdt%3AP14%20%3Fposition.%0A%20%20%3Fposition%20wdt%3AP14%20%3Fcourse.%0A%20%20%3Fcourse%20wdt%3AP3%20wd%3AQ170.%0A%20%20%7D%7D%20%0A%20%20%7B%20Select%20(COUNT%20(DISTINCT%20%3Fmodule)%20as%20%3Fmodules)%20WHERE%20%7B%0A%20%20wd%3AQ790%20wdt%3AP14%20%3Fmodule.%0A%20%20%3Fmodule%20wdt%3AP3%20wd%3AQ791.%0A%20%20%7D%7D%0A%20%20%7B%20Select%20(COUNT%20(DISTINCT%20%3Fterm)%20as%20%3Fterms)%20WHERE%20%7B%0A%20%20wd%3AQ790%20wdt%3AP14%20%3Fmodule.%0A%20%20%3Fmodule%20wdt%3AP3%20wd%3AQ791.%0A%20%20%3Fmodule%20wdt%3AP34%20%3Fterm%0A%20%20%7D%7D%0A%20%20%23%20FILTER(!regex(%3FcourseLabel%2C%20%22%5B0-9%5D%7B2%7D%22%2C%20%22i%22))%0A%0A%20%20service%20wikibase%3Alabel%20%7B%20bd%3AserviceParam%20wikibase%3Alanguage%20%22de%22.%7D%0A%7D%20&format=json |format=json |use jsonpath |data= modules=$.results.bindings[0].modules.value, positions=$.results.bindings[0].positions.value, terms=$.results.bindings[0].terms.value, }} Der Studiengang hat {{#external_value:modules}} Module mit {{#external_value:positions}} Kursen in einer Regelstudienzeit von {{#external_value:terms}} Semestern.

Studiengang

Links zu verschiedenen Visualisierungen

Beschreibung	Query-Ergebnis	SPARQL-Query
Kurse pro Semester	https://tinyurl.com/2d4l76x9	https://tinyurl.com/2852we9m
Kurse (mit Tags) pro Semester	https://tinyurl.com/2c2sfdsq	https://tinyurl.com/2bsmgm3m
Bar Chart: Kurse pro Semester	http://tinyurl.com/22hybdbp	http://tinyurl.com/2aza77az

Modulplan

Zeigt die Abhängigkeiten zwischen Modulen, sowie deren relevanten Modulpositionen Items used: M. Sc. Media Informatics (Q2886), Module (Q791), Mandatory (Q324)

Properties used: includes (P14), instance of (P3), depends on (P1), importance (P13)

#defaultView:Graph
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
PREFIX wd: <https://graphit.ur.de/entity/>
PREFIX p: <https://graphit.ur.de/prop/>
PREFIX ps: <https://graphit.ur.de/prop/statement/>
PREFIX pq: <https://graphit.ur.de/prop/qualifier/>
select distinct ?module ?moduleLabel ?rgb ?module2 ?module2Label
?position ?positionLabel 
# ?pCount
?course ?courseLabel
where {
  wd:Q2886 wdt:P14 ?module.
  ?module wdt:P3 wd:Q791.
  
  {
    
    # Only show a module position, if there are >1 included in a module.
    { SELECT ?module ?moduleLabel (COUNT(?position) as ?pCount) WHERE {
       ?module wdt:P14 ?position.
    } GROUP BY ?module ?moduleLabel
    }
    ?module wdt:P14 ?position.
    FILTER (?pCount > 1). 
  
  } UNION {
    
    # Select all other module normally
    { SELECT ?module ?moduleLabel ?module2 ?module2Label ?course ?courseLabel 
    WHERE {
      wd:Q2886 wdt:P14 ?module.
      ?module wdt:P3 wd:Q791.
      ?module wdt:P14 ?position.
      
      # Show the dependencies according to their importance (=qualifier), currently only "Mandatory" (Q324)
      OPTIONAL {
        ?module p:P1 ?statement.
        ?statement ps:P1 ?module2. 
        ?statement pq:P13 wd:Q324. # exclude this line to show dependencies of diff importance
      } 
      #OPTIONAL {?position wdt:P14 ?course}
    }
    }
    
  }
 
  BIND (IF(BOUND(?module2), "ffeec2","e3ffd9") as ?rgb)
  
  service wikibase:label { bd:serviceParam wikibase:language "de".}
} LIMIT 50

Try it!

Detailansicht

Zeigt die Module, Modulpositionen und Kurse abhängig von Semester Items used: M. Sc. Media Informatics (Q2886), Module (Q791), Course (Q170), Mandatory (Q324)

Properties used: includes (P14), instance of (P3), in term (P34), has tag (P35), depends on (P1), importance (P13)

#defaultView:Graph
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
PREFIX wd: <https://graphit.ur.de/entity/>
PREFIX p: <https://graphit.ur.de/prop/>
PREFIX ps: <https://graphit.ur.de/prop/statement/>
PREFIX pq: <https://graphit.ur.de/prop/qualifier/>
SELECT DISTINCT
?position ?positionLabel
?module ?moduleLabel ?rgb ?module2 ?module2Label 
?course ?courseLabel 
# ?tag ?tagLabel 
?term ?termLabel # show relation to terms
WHERE { # Module -> Moduleposition -> Course
  
  {
  # Structure: module -> positions -> course
  { SELECT * WHERE {
    wd:Q2886 wdt:P14 ?module.
    ?module wdt:P3 wd:Q791.
    ?module wdt:P14 ?position.
    ?position wdt:P14 ?course.
    ?course wdt:P3 wd:Q170.
    OPTIONAL {?position wdt:P34 ?term.} # term
    
    # Use "Kürzel" as labels for ?position 
    ?position skos:altLabel ?pAlias. 
    FILTER regex(?pAlias, "BA", "i").
    BIND(IF(BOUND(?pAlias), ?pAlias, ?positionLabel) as ?positionLabel).
    
    # Only show a module position, if there are >1 included in a module.
    { SELECT ?module ?moduleLabel (COUNT(?position) as ?pCount) WHERE {
       ?module wdt:P14 ?position.
    } GROUP BY ?module ?moduleLabel
    }
    ?module wdt:P14 ?position.
    FILTER (?pCount > 1).
  } }
  } UNION {
  # Structure: module -> course
  { SELECT ?module ?moduleLabel ?course ?courseLabel ?module2 ?module2Label ?term ?termLabel
  WHERE { # module -> course
    wd:Q2886 wdt:P14 ?module.
    ?module wdt:P3 wd:Q791.
    ?module wdt:P14 ?position.
    ?position wdt:P14 ?course.
    ?course wdt:P3 wd:Q170.
    ?module wdt:P34 ?term. # term
    
    # Filter out all module positions for modules with only one position
    { SELECT ?module ?moduleLabel (COUNT(?position) as ?pCount) WHERE {
       ?module wdt:P14 ?position.
    } GROUP BY ?module ?moduleLabel
    }
    ?module wdt:P14 ?position.
    FILTER (?pCount = 1). 
    
    # Show the dependencies according to their importance (=qualifier), currently only "Mandatory" (Q324)
    OPTIONAL {
        ?module p:P1 ?statement.
        ?statement ps:P1 ?module2. 
        ?statement pq:P13 wd:Q324. # exclude this line to show dependencies of diff importance
      } 
  } }
  }
  
  # OPTIONAL {?module wdt:P35 ?tag.} # hängt an module
  BIND (IF(BOUND(?module2), "ffeec2","e3ffd9") as ?rgb)
  
  # Use alias for courses -> e.g. OOP
  OPTIONAL { 
    ?course skos:altLabel ?cAlias.
    BIND(IF(BOUND(?cAlias), ?cAlias, ?courseLabel) as ?courseLabel). 
  } # REMOVE to show FULL COURSE LABELS
  
  # Only show exemplary courses -> no ~ WS/SS23
  FILTER(!regex(?courseLabel, "[0-9]{2}", "i"))
  
  
  service wikibase:label { bd:serviceParam wikibase:language "de".}
} LIMIT 50

Try it!

Alternativ

Zeigt Module und deren Kurse in Abhängigkeit an.

Items used: M. Sc. Media Informatics (Q2886), Module (Q791), Course (Q170), Mandatory (Q324)

Properties used: includes (P14), instance of (P3), depends on (P1), importance (P13)

#defaultView:Graph
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
PREFIX wd: <https://graphit.ur.de/entity/>
PREFIX p: <https://graphit.ur.de/prop/>
PREFIX ps: <https://graphit.ur.de/prop/statement/>
PREFIX pq: <https://graphit.ur.de/prop/qualifier/>
SELECT DISTINCT
?module ?moduleLabel ?rgb
# ?mPos ?mPosLabel
?depend ?dependLabel 
?course ?courseLabel 
WHERE {
  wd:Q2886 wdt:P14 ?module.
  ?module wdt:P3 wd:Q791.
  ?module wdt:P14+ ?course. # Module -> (Modulepos) -> Course
  ?course wdt:P3 wd:Q170.
  
  # Show the dependencies according to their importance (=qualifier), currently only "Mandatory" (Q324)
  OPTIONAL {
    ?module p:P1 ?statement.
    ?statement ps:P1 ?depend. 
    ?statement pq:P13 wd:Q324. # exclude this line to show dependencies of diff importance
  } 
  
  BIND (IF(BOUND(?depend), "ffeec2","e3ffd9") as ?rgb)
  service wikibase:label { bd:serviceParam wikibase:language "de".}
} LIMIT 50

Try it!

Empfohlene Fachsemester

Empfohlene Fachsemester für die Module

Zusätzliche Queries

Studiengangsmetriken

Gibt zurück Anzahl der Module, Modulpositionen(=Kurse) und Semester.

Items used: M. Sc. Media Informatics (Q2886), Module (Q791), Course (Q170)

Properties used: includes (P14), instance of (P3), in term (P34)

#defaultView:Table
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
PREFIX wd: <https://graphit.ur.de/entity/>
SELECT DISTINCT ?modules ?positions ?terms 
WHERE {
  { Select (COUNT (DISTINCT ?position) as ?positions) WHERE {
  wd:Q2886 wdt:P14 ?module.
  ?module wdt:P3 wd:Q791.
  ?module wdt:P14 ?position.
  ?position wdt:P14 ?course.
  ?course wdt:P3 wd:Q170.
  } } 
  { Select (COUNT (DISTINCT ?module) as ?modules) WHERE {
  wd:Q2886 wdt:P14 ?module.
  ?module wdt:P3 wd:Q791.
  } }
  { Select (COUNT (DISTINCT ?term) as ?terms) WHERE {
  wd:Q2886 wdt:P14 ?module.
  ?module wdt:P3 wd:Q791.
  ?module wdt:P34 ?term.
  } }
  service wikibase:label { bd:serviceParam wikibase:language "de".}
}

Try it!

Media Informatics Msc

Contents

Studiengang

Modulplan

Detailansicht

Empfohlene Fachsemester

Zusätzliche Queries