Medieninformatik Msc

Dies ist Übersicht für den Studiengang Medieninformatik (Master of Science) an der Universität Regensburg.

ℹ️ Für direkte Informationen nutzen Sie die offizielle Homepage

Der Studiengang hat 16 Module mit 25 Kursen in einer Regelstudienzeit von 4 Semestern.

Modulplan

Zeigt die Abhängigkeiten zwischen Modulen, sowie deren relevanten Modulpositionen Items used: M. Sc. Media Informatics (Q2886), Module (Q791), Mandatory (Q324)

Properties used: includes (P14), instance of (P3), depends on (P1), importance (P13)

#defaultView:Graph
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
PREFIX wd: <https://graphit.ur.de/entity/>
PREFIX p: <https://graphit.ur.de/prop/>
PREFIX ps: <https://graphit.ur.de/prop/statement/>
PREFIX pq: <https://graphit.ur.de/prop/qualifier/>
select distinct ?module ?moduleLabel ?rgb ?module2 ?module2Label
?position ?positionLabel 
# ?pCount
?course ?courseLabel
where {
  wd:Q2886 wdt:P14 ?module.
  ?module wdt:P3 wd:Q791.
  
  {
    
    # Only show a module position, if there are >1 included in a module.
    { SELECT ?module ?moduleLabel (COUNT(?position) as ?pCount) WHERE {
       ?module wdt:P14 ?position.
    } GROUP BY ?module ?moduleLabel
    }
    ?module wdt:P14 ?position.
    FILTER (?pCount > 1). 
  
  } UNION {
    
    # Select all other module normally
    { SELECT ?module ?moduleLabel ?module2 ?module2Label ?course ?courseLabel 
    WHERE {
      wd:Q2886 wdt:P14 ?module.
      ?module wdt:P3 wd:Q791.
      ?module wdt:P14 ?position.
      
      # Show the dependencies according to their importance (=qualifier), currently only "Mandatory" (Q324)
      OPTIONAL {
        ?module p:P1 ?statement.
        ?statement ps:P1 ?module2. 
        ?statement pq:P13 wd:Q324. # exclude this line to show dependencies of diff importance
      } 
      #OPTIONAL {?position wdt:P14 ?course}
    }
    }
    
  }
 
  BIND (IF(BOUND(?module2), "ffeec2","e3ffd9") as ?rgb)
  
  service wikibase:label { bd:serviceParam wikibase:language "de".}
} LIMIT 50

Try it!

Detailansicht

Zeigt die Module, Modulpositionen und Kurse abhängig von Semester Items used: M. Sc. Media Informatics (Q2886), Module (Q791), Module position (Q792)

Properties used: includes (P14), instance of (P3), in term (P34), depends on (P1)

#defaultView:Graph
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
PREFIX wd: <https://graphit.ur.de/entity/>
PREFIX p: <https://graphit.ur.de/prop/>
PREFIX ps: <https://graphit.ur.de/prop/statement/>
PREFIX pq: <https://graphit.ur.de/prop/qualifier/>

# Select all relevant variables for the graph visualization:
# - position & positionLabel: the module position (e.g. compulsory, elective)
# - module & moduleLabel: the module itself
# - rgb: color coding (yellow = has dependencies, green = no dependencies)
# - module2 & module2Label: a dependency of a module (if any)
# - term & termLabel: the recommended semester for the module
SELECT DISTINCT
?position ?positionLabel
?module ?moduleLabel ?rgb ?module2 ?module2Label 
?term ?termLabel
WHERE {


  # Handles modules that have MORE THAN ONE position (e.g. listed under both
  # compulsory and elective). For these, we show the position nodes explicitly
  # in the graph, since the position itself carries meaning.
  {
  { SELECT * WHERE {
    wd:Q2886 wdt:P14 ?module.
    ?module wdt:P3 wd:Q791.
    ?module wdt:P14 ?position.
    ?position wdt:P3 wd:Q792.
    OPTIONAL {?position wdt:P34 ?term.}
    
    # Count how many positions each module has
    { SELECT ?module ?moduleLabel (COUNT(?position) as ?pCount) WHERE {
       ?module wdt:P14 ?position.
    } GROUP BY ?module ?moduleLabel
    }
    # Re-join to get the actual position triples (needed after the subquery)
    ?module wdt:P14 ?position.
    # Only keep modules that appear in more than one position
    FILTER (?pCount > 1).
  } }
  }

  UNION


  # Handles modules that have EXACTLY ONE position. For these, the position is
  # less visually interesting, so we skip it and instead show dependencies and
  # the recommended semester directly on the module node.
  {
  { SELECT ?module ?moduleLabel ?module2 ?module2Label ?term ?termLabel
  WHERE {
    wd:Q2886 wdt:P14 ?module.
    ?module wdt:P3 wd:Q791.
    ?module wdt:P14 ?position.
    ?position wdt:P3 wd:Q792.
    ?module wdt:P34 ?term.
    
    # Count how many positions each module has
    { SELECT ?module ?moduleLabel (COUNT(?position) as ?pCount) WHERE {
       ?module wdt:P14 ?position.
    } GROUP BY ?module ?moduleLabel
    }
    # Re-join positions after subquery
    ?module wdt:P14 ?position.
    # Only keep modules that appear in exactly one position
    FILTER (?pCount = 1). 
    
    # Optionally fetch dependencies: module -> P1 (depends on) -> module2
    # The statement/ps pattern allows access to qualifiers if needed later
    OPTIONAL {
        ?module p:P1 ?statement.
        ?statement ps:P1 ?module2. 
      } 
  } }
  }
  
  # ─── COLOR CODING ───────────────────────────────────────────────────────────
  # Assign a background color to each module node in the graph:
  # - "ffeec2" (yellow) if the module has a dependency (module2 is bound)
  # - "e3ffd9" (green)  if the module has no dependency
  BIND (IF(BOUND(?module2), "ffeec2","e3ffd9") as ?rgb)
  
  # ─── LABELS ─────────────────────────────────────────────────────────────────
 
  service wikibase:label { bd:serviceParam wikibase:language "en".}

} LIMIT 50

Try it!

}}

Allgemeine Informationen

Studiengangsmetriken

Gibt zurück Anzahl der Module, Modulpositionen und Semester. Items used: M. Sc. Media Informatics (Q2886), Module (Q791), Module position (Q792) Properties used: includes (P14), instance of (P3), in term (P34) #defaultView:Table PREFIX wdt: <https://graphit.ur.de/prop/direct/> PREFIX wd: <https://graphit.ur.de/entity/> SELECT DISTINCT ?modules ?positions ?terms WHERE { { Select (COUNT (DISTINCT ?position) as ?positions) WHERE { wd:Q2886 wdt:P14 ?module. ?module wdt:P3 wd:Q791. ?module wdt:P14 ?position. ?position wdt:P3 wd:Q792 } } { Select (COUNT (DISTINCT ?module) as ?modules) WHERE { wd:Q2886 wdt:P14 ?module. ?module wdt:P3 wd:Q791. } } { Select (COUNT (DISTINCT ?term) as ?terms) WHERE { wd:Q2886 wdt:P14 ?module. ?module wdt:P3 wd:Q791. ?module wdt:P34 ?term. } } service wikibase:label { bd:serviceParam wikibase:language "en".} } Try it!