Medieninformatik BA: Difference between revisions

(→‎Modulplan: added link table to queries)
(→‎Studiengang: added to table + changed queries from widget to code)
Line 20: Line 20:
|-
|-
| Kurse (mit Tags) pro Semester || http://tinyurl.com/27s9vaut || http://tinyurl.com/2bvg3qg9
| Kurse (mit Tags) pro Semester || http://tinyurl.com/27s9vaut || http://tinyurl.com/2bvg3qg9
|-
| Bar Chart: Kurse pro Semester || http://tinyurl.com/22hybdbp || http://tinyurl.com/2aza77az
|}
|}


== Modulplan ==
== Modulplan ==
{{#widget:SPARQLquery|code=
Zeigt die Abhängigkeiten zwischen Modulen, sowie deren relevanten Modulpositionen
{{SPARQL2|query=
#defaultView:Graph
#defaultView:Graph
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
Line 73: Line 76:
   service wikibase:label { bd:serviceParam wikibase:language "de".}
   service wikibase:label { bd:serviceParam wikibase:language "de".}
} LIMIT 50
} LIMIT 50
| caption=Abhängigkeiten zwischen Modulen, sowie deren relevanten Modulpositionen
}}
}}


== Detailansicht ==  
== Detailansicht ==  
 
Zeigt die Module, Modulpositionen und Kurse abhängig von Semester
{{#widget:SPARQLquery|code=
{{SPARQL2|query=
#defaultView:Graph
#defaultView:Graph
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
Line 158: Line 160:
    
    
   service wikibase:label { bd:serviceParam wikibase:language "de".}
   service wikibase:label { bd:serviceParam wikibase:language "de".}
} LIMIT 50 |caption=Module, Modulpositionen und Kurse abhängig von Semester
} LIMIT 50
}}  
}}  


Revision as of 15:57, 21 February 2024

Dies ist Übersicht für den Studiengang Medieninformatik (Bachelor of Arts) an der Universität Regensburg.

💡Info! Für direkte Informationen nutzen Sie die offizielle Homepage


Der Studiengang hat 14 Module mit 17 Kursen in einer Regelstudienzeit von 6 Semestern.

Studiengang

Links zu verschiedenen Visualisierungen

Beschreibung Query-Ergebnis SPARQL-Query
Kurse pro Semester http://tinyurl.com/2aza77az http://tinyurl.com/2ckcypph
Kurse (mit Tags) pro Semester http://tinyurl.com/27s9vaut http://tinyurl.com/2bvg3qg9
Bar Chart: Kurse pro Semester http://tinyurl.com/22hybdbp http://tinyurl.com/2aza77az

Modulplan

Zeigt die Abhängigkeiten zwischen Modulen, sowie deren relevanten Modulpositionen Items used: Media informatics B.A. UR (Q790), Module (Q791), Mandatory (Q324)

Properties used: includes (P14), instance of (P3), depends on (P1), importance (P13) 

#defaultView:Graph
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
PREFIX wd: <https://graphit.ur.de/entity/>
PREFIX p: <https://graphit.ur.de/prop/>
PREFIX ps: <https://graphit.ur.de/prop/statement/>
PREFIX pq: <https://graphit.ur.de/prop/qualifier/>
select distinct ?module ?moduleLabel ?rgb ?module2 ?module2Label
?position ?positionLabel 
# ?pCount
?course ?courseLabel
where {
  wd:Q790 wdt:P14 ?module.
  ?module wdt:P3 wd:Q791.
  
  {
    
    # Only show a module position, if there are >1 included in a module.
    { SELECT ?module ?moduleLabel (COUNT(?position) as ?pCount) WHERE {
       ?module wdt:P14 ?position.
    } GROUP BY ?module ?moduleLabel
    }
    ?module wdt:P14 ?position.
    FILTER (?pCount > 1). 
  
  } UNION {
    
    # Select all other module normally
    { SELECT ?module ?moduleLabel ?module2 ?module2Label ?course ?courseLabel 
    WHERE {
      wd:Q790 wdt:P14 ?module.
      ?module wdt:P3 wd:Q791.
      ?module wdt:P14 ?position.
      
      # Show the dependencies according to their importance (=qualifier), currently only "Mandatory" (Q324)
      OPTIONAL {
        ?module p:P1 ?statement.
        ?statement ps:P1 ?module2. 
        ?statement pq:P13 wd:Q324. # exclude this line to show dependencies of diff importance
      } 
      #OPTIONAL {?position wdt:P14 ?course}
    }
    }
    
  }
 
  BIND (IF(BOUND(?module2), "ffeec2","e3ffd9") as ?rgb)
  
  service wikibase:label { bd:serviceParam wikibase:language "de".}
} LIMIT 50

Try it!


Detailansicht

Zeigt die Module, Modulpositionen und Kurse abhängig von Semester Items used: Media informatics B.A. UR (Q790), Module (Q791), Course (Q170), Mandatory (Q324)

Properties used: includes (P14), instance of (P3), in term (P34), has tag (P35), depends on (P1), importance (P13) 

#defaultView:Graph
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
PREFIX wd: <https://graphit.ur.de/entity/>
PREFIX p: <https://graphit.ur.de/prop/>
PREFIX ps: <https://graphit.ur.de/prop/statement/>
PREFIX pq: <https://graphit.ur.de/prop/qualifier/>
SELECT DISTINCT
?position ?positionLabel
?module ?moduleLabel ?rgb ?module2 ?module2Label 
?course ?courseLabel 
# ?tag ?tagLabel 
?term ?termLabel # show relation to terms
WHERE { # Module -> Moduleposition -> Course
  
  {
  # Structure: module -> positions -> course
  { SELECT * WHERE {
    wd:Q790 wdt:P14 ?module.
    ?module wdt:P3 wd:Q791.
    ?module wdt:P14 ?position.
    ?position wdt:P14 ?course.
    ?course wdt:P3 wd:Q170.
    OPTIONAL {?position wdt:P34 ?term.} # term
    
    # Use "Kürzel" as labels for ?position 
    ?position skos:altLabel ?pAlias. 
    FILTER regex(?pAlias, "BA", "i").
    BIND(IF(BOUND(?pAlias), ?pAlias, ?positionLabel) as ?positionLabel).
    
    # Only show a module position, if there are >1 included in a module.
    { SELECT ?module ?moduleLabel (COUNT(?position) as ?pCount) WHERE {
       ?module wdt:P14 ?position.
    } GROUP BY ?module ?moduleLabel
    }
    ?module wdt:P14 ?position.
    FILTER (?pCount > 1).
  } }
  } UNION {
  # Structure: module -> course
  { SELECT ?module ?moduleLabel ?course ?courseLabel ?module2 ?module2Label ?term ?termLabel
  WHERE { # module -> course
    wd:Q790 wdt:P14 ?module.
    ?module wdt:P3 wd:Q791.
    ?module wdt:P14 ?position.
    ?position wdt:P14 ?course.
    ?course wdt:P3 wd:Q170.
    ?module wdt:P34 ?term. # term
    
    # Filter out all module positions for modules with only one position
    { SELECT ?module ?moduleLabel (COUNT(?position) as ?pCount) WHERE {
       ?module wdt:P14 ?position.
    } GROUP BY ?module ?moduleLabel
    }
    ?module wdt:P14 ?position.
    FILTER (?pCount = 1). 
    
    # Show the dependencies according to their importance (=qualifier), currently only "Mandatory" (Q324)
    OPTIONAL {
        ?module p:P1 ?statement.
        ?statement ps:P1 ?module2. 
        ?statement pq:P13 wd:Q324. # exclude this line to show dependencies of diff importance
      } 
  } }
  }
  
  # OPTIONAL {?module wdt:P35 ?tag.} # hängt an module
  BIND (IF(BOUND(?module2), "ffeec2","e3ffd9") as ?rgb)
  
  # Use alias for courses -> e.g. OOP
  OPTIONAL { 
    ?course skos:altLabel ?cAlias.
    BIND(IF(BOUND(?cAlias), ?cAlias, ?courseLabel) as ?courseLabel). 
  } # REMOVE to show FULL COURSE LABELS
  
  # Only show exemplary courses -> no ~ WS/SS23
  FILTER(!regex(?courseLabel, "[0-9]{2}", "i"))
  
  
  service wikibase:label { bd:serviceParam wikibase:language "de".}
} LIMIT 50

Try it!



Alternativ
Zeigt Module und deren Kurse in Abhängigkeit an.

Items used: Media informatics B.A. UR (Q790), Module (Q791), Course (Q170), Mandatory (Q324)

Properties used: includes (P14), instance of (P3), depends on (P1), importance (P13) 

#defaultView:Graph
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
PREFIX wd: <https://graphit.ur.de/entity/>
PREFIX p: <https://graphit.ur.de/prop/>
PREFIX ps: <https://graphit.ur.de/prop/statement/>
PREFIX pq: <https://graphit.ur.de/prop/qualifier/>
SELECT DISTINCT
?module ?moduleLabel ?rgb
# ?mPos ?mPosLabel
?depend ?dependLabel 
?course ?courseLabel 
WHERE {
  wd:Q790 wdt:P14 ?module.
  ?module wdt:P3 wd:Q791.
  ?module wdt:P14+ ?course. # Module -> (Modulepos) -> Course
  ?course wdt:P3 wd:Q170.
  
  # Show the dependencies according to their importance (=qualifier), currently only "Mandatory" (Q324)
  OPTIONAL {
    ?module p:P1 ?statement.
    ?statement ps:P1 ?depend. 
    ?statement pq:P13 wd:Q324. # exclude this line to show dependencies of diff importance
  } 
  
  BIND (IF(BOUND(?depend), "ffeec2","e3ffd9") as ?rgb)
  service wikibase:label { bd:serviceParam wikibase:language "de".}
} LIMIT 50

Try it!


Empfohlene Fachsemester

Empfohlene Fachsemester für die Module

Zustätzliche Queries

Studiengangsmetriken
Gibt zurück Anzahl der Module, Modulpositionen(=Kurse) und Semester.

Items used: Media informatics B.A. UR (Q790), Module (Q791), Course (Q170)

Properties used: includes (P14), instance of (P3), in term (P34) 

#defaultView:Table
PREFIX wdt: <https://graphit.ur.de/prop/direct/>
PREFIX wd: <https://graphit.ur.de/entity/>
SELECT DISTINCT ?modules ?positions ?terms 
WHERE {
  { Select (COUNT (DISTINCT ?position) as ?positions) WHERE {
  wd:Q790 wdt:P14 ?module.
  ?module wdt:P3 wd:Q791.
  ?module wdt:P14 ?position.
  ?position wdt:P14 ?course.
  ?course wdt:P3 wd:Q170.
  } } 
  { Select (COUNT (DISTINCT ?module) as ?modules) WHERE {
  wd:Q790 wdt:P14 ?module.
  ?module wdt:P3 wd:Q791.
  } }
  { Select (COUNT (DISTINCT ?term) as ?terms) WHERE {
  wd:Q790 wdt:P14 ?module.
  ?module wdt:P3 wd:Q791.
  ?module wdt:P34 ?term.
  } }
  service wikibase:label { bd:serviceParam wikibase:language "de".}
}

Try it!


Retrieved from "https://graphit.ur.de/w/index.php?title=Medieninformatik_BA&oldid=6662"